{deck}
version:1
card:0
size:[512,342]
name:"loveletter.deck"

{fonts}
olympiad_italic:"%%[encoded data, 5256 characters]"

{card:home}
script:"home.0"
{widgets}
field1:{"type":"field","size":[253,26],"pos":[7,307],"locked":1,"show":"invert","border":0,"align":"center","value":{"text":["loosely adapted from ","Love Letters",",\nwith apologies to Alan Turing and Christopher Strachey"],"font":["","",""],"arg":["","https://nickm.com/memslam/love_letters.html",""]}}
prose:{"type":"field","size":[498,289],"pos":[12,14],"volatile":1,"font":"olympiad_italic","border":0}
button1:{"type":"button","size":[188,26],"pos":[317,307],"script":"home.1","text":"Tell me again, Dearest..."}

{script:home.0}
adjectives:"%j" parse "[
 'adorable', 'affectionate', 'amorous', 'anxious', 
 'ardent', 'avid', 'breathless', 'burning', 'covetous', 'craving', 
 'curious', 'darling', 'dear', 'devoted', 'eager', 'erotic', 
 'fervent', 'fond', 'impatient', 'keen', 'little', 'loveable', 
 'lovesick', 'loving', 'passionate', 'precious', 'sweet', 
 'sympathetic', 'tender', 'unsatisfied', 'wistful',
 'feathered', 'beaked', 'tittering', 'preening', 'broody',
]"
nouns:"%j" parse "[
 'adoration', 'affection', 'ambition', 'appetite', 'ardour', 
 'charm', 'desire', 'devotion', 'eagerness', 'enchantment', 
 'enthusiasm', 'fancy', 'fellow feeling', 'fervour', 'fondness', 
 'heart', 'hunger', 'infatuation', 'liking', 'longing', 'love', 
 'lust', 'passion', 'rapture', 'sympathy', 'tenderness', 'thirst', 
 'wish', 'yearning', 'bird', 'egg', 'corn', 'bug',
 'desire for bugs', 'desire for corn', 'fluffiness',
]"
adverbs:"%j" parse "[
 'affectionately', 'anxiously', 'ardently', 'avidly', 
 'beautifully', 'breathlessly', 'burningly', 'covetously', 
 'curiously', 'devotedly', 'eagerly', 'fervently', 'fondly', 
 'impatiently', 'keenly', 'lovingly', 'passionately', 'seductively',
 'tenderly', 'winningly', 'wistfully',
]"
verbs:"%j" parse "[
 'adores', 'attracts', 'cares for', 'cherishes', 'clings to', 
 'desires', 'holds dear', 'hopes for', 'hungers for', 
 'is wedded to', 'likes', 'longs for', 'loves', 'lusts after', 
 'pants for', 'pines for', 'prizes', 'sighs for', 'tempts', 
 'thirsts for', 'treasures', 'wants', 'wishes', 'woos', 
 'yearns for', 'offers a bug to', 'warms the egg of', 'trills at'
]"

on maybe words do
 if random[2] " %s" format random[words] else "" end
end
on shorter do
 " %s %s." format random[adjectives],random[nouns]
end
on longer do
 " My%s %s%s %s your%s %s." format
  maybe[adjectives],random[nouns],maybe[adverbs],
  random[verbs],maybe[adjectives],random[nouns]
end
on greeting do
 "%s %s,\n\n" format
  random["Darling","Dear","Honey","Jewel"],
  random["chicken","love","user","sweetheart"]
end
on closing do
 "\n\n    Yours %s,\n      Decker" format random[adverbs]
end
on letter do
 local f:0
 "" fuse greeting[],each in range 8
  if random[2] f:0 longer[]
  elseif f     f:0 " My%s" format shorter[]
  else         f:1 " You are my%s" format shorter[]
  end
 end,closing[]
end

on view do
 prose.text:letter[]
end
{end}

{script:home.1}
on click do
 view[]
end
{end}

