Hull
    name = "SH_BIOADAPTIVE"
    description = "SH_BIOADAPTIVE_DESC"
    speed = 100
    fuel = 1
    NoDefaultFuelEffect
    stealth = 35
    structure = 15
    slots = [
        Slot type = External position = (0.30, 0.35)
        Slot type = External position = (0.50, 0.35)
        Slot type = External position = (0.70, 0.35)
        Slot type = Internal position = (0.20, 0.65)
        Slot type = Internal position = (0.40, 0.65)
        Slot type = Internal position = (0.60, 0.65)
    ]
    buildcost = 21 * [[FLEET_UPKEEP_MULTIPLICATOR]] * [[SHIP_HULL_COST_MULTIPLIER]]
    buildtime = 6
    tags = [ "ORGANIC_HULL" "PEDIA_HULL_LINE_ORGANIC" "AVERAGE_FUEL_EFFICIENCY" ]
    location = And [
        Planet
        OwnedBy empire = Source.Owner
        Contains And [
            Building name = "BLD_SHIPYARD_ORG_CELL_GRO_CHAMB"
            OwnedBy empire = Source.Owner
        ]
        Contains And [
            Building name = "BLD_SHIPYARD_ORG_ORB_INC"
            OwnedBy empire = Source.Owner
        ]
        Contains And [
            Building name = "BLD_SHIPYARD_BASE"
            OwnedBy empire = Source.Owner
        ]
    ]
    effectsgroups = [
        EffectsGroup
            scope = Source
            activation = Turn low = Source.CreationTurn + 1
            effects = [
                SetStructure value =  Value + Value
            ]

        EffectsGroup
            scope = Source
            effects = SetDetection value = Value + 75

        EffectsGroup
            scope = Source
            accountinglabel = "ORGANIC_GROWTH"
            effects = SetMaxStructure value = Value + ( min(Source.Age*0.5, 25) * [[SHIP_STRUCTURE_FACTOR]] )

        [[AVERAGE_FUEL_EFFICIENCY]]
        [[ADD_HULL_FUEL_TO_MAX_FUEL_METER]]
        [[LIVING_HULL_BASE_FUEL_REGEN]]
        [[SCAVANGE_FUEL_UNOWNED]]
        [[UNOWNED_GOOD_VISION]]
        [[UNOWNED_MOVE]]
    ]
    icon = "icons/ship_hulls/bio_adaptive_hull_small.png"
    graphic = "hulls_design/bio_adaptive_hull.png"

#include "organic.macros"

#include "../ship_hulls.macros"

#include "/scripting/macros/upkeep.macros"
